cmake_minimum_required(VERSION 3.16)
project(Refall C CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
# Release by default (stored in the cache so tools and IDEs show it). Multi-config generators
# (Visual Studio, Xcode) choose the configuration at build time: cmake --build build --config Release.
get_property(REFALL_MULTI_CONFIG GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
if(NOT REFALL_MULTI_CONFIG AND NOT CMAKE_BUILD_TYPE)
  set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (Debug, Release, RelWithDebInfo, MinSizeRel)" FORCE)
endif()
if(NOT REFALL_MULTI_CONFIG)
  message(STATUS "Refall build type: ${CMAKE_BUILD_TYPE}")
endif()

# A standalone build (REFALL_STANDALONE=ON: the Windows .exe of the releases) is one file with nothing beside it:
# the menu's music and the gamepad mappings built in, the C/C++ runtime linked statically, no console window, and
# yt-dlp, ffmpeg and deno fetched on first use (platform::ensureTools, src/platform.cpp).
option(REFALL_STANDALONE "One self-contained executable (the Windows release)" OFF)
if(REFALL_STANDALONE)
  set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
  set(USE_MSVC_RUNTIME_LIBRARY_DLL OFF CACHE BOOL "" FORCE) # (GLFW's own switch)
  add_compile_definitions(REFALL_STANDALONE)
endif()

# GLFW: the system one by default; REFALL_BUNDLE_GLFW=ON (used for Python wheels) builds it from
# source and links it statically, so the binaries only need the system's OpenGL/X11 at runtime.
option(REFALL_BUNDLE_GLFW "Build GLFW from source and link it statically" OFF)
if(NOT REFALL_BUNDLE_GLFW)
  find_package(glfw3 QUIET)
endif()
if(REFALL_BUNDLE_GLFW OR NOT glfw3_FOUND)
  include(FetchContent)
  set(GLFW_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
  set(GLFW_BUILD_TESTS OFF CACHE BOOL "" FORCE)
  set(GLFW_BUILD_DOCS OFF CACHE BOOL "" FORCE)
  set(GLFW_INSTALL OFF CACHE BOOL "" FORCE)
  set(GLFW_BUILD_WAYLAND OFF CACHE BOOL "" FORCE) # X11 (also runs under XWayland)
  set(BUILD_SHARED_LIBS OFF CACHE BOOL "" FORCE)
  FetchContent_Declare(glfw GIT_REPOSITORY https://github.com/glfw/glfw.git GIT_TAG 3.4 GIT_SHALLOW TRUE)
  FetchContent_MakeAvailable(glfw)
endif()
find_package(Threads REQUIRED)

# OpenGL 3.3 core function loader (generated by glad, loaded at runtime through GLFW).
add_library(glad STATIC third_party/glad/src/gl.c)
target_include_directories(glad PUBLIC third_party/glad/include)
set_target_properties(glad PROPERTIES POSITION_INDEPENDENT_CODE ON)

# qu3e: a small rigid body engine for boxes (zlib license), WHITE ROOM's cleared cubes piling up on the floor.
file(GLOB_RECURSE QU3E_SOURCES CONFIGURE_DEPENDS third_party/qu3e/src/*.cpp)
add_library(qu3e STATIC ${QU3E_SOURCES})
target_include_directories(qu3e SYSTEM PUBLIC third_party/qu3e/src)
set_target_properties(qu3e PROPERTIES POSITION_INDEPENDENT_CODE ON)
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  target_compile_options(qu3e PRIVATE -w)
endif()

# Audio decoding, analysis and song planning, shared by the game and the analysis viewer.
add_library(refallcore STATIC
  src/analysis.cpp
  src/audio.cpp
  src/samples.cpp
  src/library.cpp
  src/titles.cpp
  src/songplan.cpp
  src/youtube.cpp
  src/platform.cpp
  src/third_party_impl.cpp
)
target_include_directories(refallcore PUBLIC src third_party)
target_link_libraries(refallcore PUBLIC Threads::Threads ${CMAKE_DL_LIBS})
if(UNIX)
  target_link_libraries(refallcore PUBLIC m)
endif()
if(MSVC)
  target_compile_options(refallcore PUBLIC /utf-8 /bigobj)
  target_compile_definitions(refallcore PUBLIC _CRT_SECURE_NO_WARNINGS NOMINMAX _USE_MATH_DEFINES)
endif()

# The renderer: the host (src/renderer.*), the transitions between universes, and every universe (one folder each
# in src/universes/, picked up automatically; the list of universes is src/universes/registry.def).
# Universes listed in REFALL_DISABLED_UNIVERSES are not built at all: their sources and assets are skipped and their
# line is dropped from the registry the game is compiled with (generated/universes/registry_enabled.def).
# An existing build directory follows changes to the default list: the cached value is replaced while it still is
# a default (the last default seen, or, in a cache from before that was recorded, any subset of the default), and
# kept once it was set by hand (-D...).
set(REFALL_DEFAULT_DISABLED "cloudscape;synthwave;garden;magnets;sunprint;embroidery;sushi;ripples;starchart;stainedglass;groceries;musicbox;specimen;microscope")
set(refall_follow_default FALSE)
if(NOT DEFINED REFALL_DISABLED_UNIVERSES)
  set(refall_follow_default TRUE)
elseif(DEFINED REFALL_LAST_DEFAULT_DISABLED)
  if("${REFALL_DISABLED_UNIVERSES}" STREQUAL "${REFALL_LAST_DEFAULT_DISABLED}")
    set(refall_follow_default TRUE)
  endif()
elseif(REFALL_DISABLED_UNIVERSES)
  set(refall_follow_default TRUE)
  foreach(id ${REFALL_DISABLED_UNIVERSES})
    if(NOT id IN_LIST REFALL_DEFAULT_DISABLED)
      set(refall_follow_default FALSE)
    endif()
  endforeach()
endif()
if(refall_follow_default)
  set(REFALL_DISABLED_UNIVERSES "${REFALL_DEFAULT_DISABLED}" CACHE STRING
      "Universes (folder names in src/universes/) left out of the build, separated by ;" FORCE)
endif()
set(REFALL_LAST_DEFAULT_DISABLED "${REFALL_DEFAULT_DISABLED}" CACHE INTERNAL "The default list of disabled universes last seen")
file(GLOB REFALL_UNIVERSE_SOURCES CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/src/universes/*/*.cpp)
foreach(id ${REFALL_DISABLED_UNIVERSES})
  list(FILTER REFALL_UNIVERSE_SOURCES EXCLUDE REGEX "/src/universes/${id}/")
endforeach()
set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/src/universes/registry.def)
file(STRINGS ${CMAKE_SOURCE_DIR}/src/universes/registry.def REFALL_REGISTRY)
set(REFALL_REGISTRY_OUT "// Generated from src/universes/registry.def without the disabled universes.\n")
foreach(line IN LISTS REFALL_REGISTRY)
  set(keep TRUE)
  foreach(id ${REFALL_DISABLED_UNIVERSES})
    if(line MATCHES "^UNIVERSE\\(${id},")
      set(keep FALSE)
    endif()
  endforeach()
  if(keep AND line MATCHES "^UNIVERSE\\(")
    string(APPEND REFALL_REGISTRY_OUT "${line}\n")
  endif()
endforeach()
file(WRITE ${CMAKE_BINARY_DIR}/generated/universes/registry_enabled.def.tmp "${REFALL_REGISTRY_OUT}")
configure_file(${CMAKE_BINARY_DIR}/generated/universes/registry_enabled.def.tmp
               ${CMAKE_BINARY_DIR}/generated/universes/registry_enabled.def COPYONLY)
if(REFALL_DISABLED_UNIVERSES)
  message(STATUS "Universes left out of the build: ${REFALL_DISABLED_UNIVERSES}")
endif()
add_library(refallrender STATIC
  src/renderer.cpp
  src/hud.cpp
  src/titlecard.cpp
  src/text.cpp
  src/transitions.cpp
  src/layout.cpp
  src/ugl.cpp
  src/universes/registry.cpp
  ${REFALL_UNIVERSE_SOURCES}
)
target_link_libraries(refallrender PUBLIC refallcore glad PRIVATE qu3e)
target_include_directories(refallrender PUBLIC src)

# Universe assets: every file in src/universes/<id>/embed/ is compiled in as a byte array, included with
# `#include "universes/<id>/<file name>.inc"` (e.g. a font: `const unsigned char TTF[] = {\n#include "..."\n};`).
file(GLOB REFALL_UNIVERSE_EMBEDS CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/src/universes/*/embed/*)
foreach(id ${REFALL_DISABLED_UNIVERSES})
  list(FILTER REFALL_UNIVERSE_EMBEDS EXCLUDE REGEX "/src/universes/${id}/")
endforeach()
# The host's own assets (src/embed/: the title card's fonts) are included as "universes/host/<file name>.inc".
file(GLOB REFALL_HOST_EMBEDS CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/src/embed/*.ttf)
foreach(f ${REFALL_UNIVERSE_EMBEDS} ${REFALL_HOST_EMBEDS})
  get_filename_component(dir ${f} DIRECTORY)
  get_filename_component(dir ${dir} DIRECTORY)
  get_filename_component(id ${dir} NAME)
  if(id STREQUAL "src")
    set(id host)
  endif()
  get_filename_component(name ${f} NAME)
  set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS ${f})
  file(READ ${f} hex HEX)
  string(REGEX REPLACE "([0-9a-f][0-9a-f])" "0x\\1," arr "${hex}")
  file(WRITE ${CMAKE_BINARY_DIR}/generated/universes/${id}/${name}.inc.tmp "${arr}\n")
  configure_file(${CMAKE_BINARY_DIR}/generated/universes/${id}/${name}.inc.tmp
                 ${CMAKE_BINARY_DIR}/generated/universes/${id}/${name}.inc COPYONLY)
endforeach()
target_include_directories(refallrender PRIVATE ${CMAKE_BINARY_DIR}/generated)
# When each universe last changed (its last commit, or its files' time when it has local changes), refreshed at
# every build: the list printed for an unknown universe shows the newest last.
set(REFALL_UNIVERSE_DATES ${CMAKE_BINARY_DIR}/generated/universes/universe_dates.def)
add_custom_target(universe_dates
  COMMAND ${CMAKE_COMMAND} -DSRC=${CMAKE_SOURCE_DIR} -DOUT=${REFALL_UNIVERSE_DATES}
          -P ${CMAKE_SOURCE_DIR}/tools/universe_dates.cmake
  BYPRODUCTS ${REFALL_UNIVERSE_DATES}
  COMMENT "Universe dates")
add_dependencies(refallrender universe_dates)

# The game, and refall-voyage-viewer: the same program started on a campaign's review (its songs in their
# universes, the computer playing, an overlay to go from song to song; REFALL_VOYAGE_VIEWER).
set(REFALL_GAME_SOURCES
  src/main.cpp
  src/game.cpp
  src/input.cpp
  src/headless.cpp
  src/campaign.cpp
  src/playlists.cpp
  src/voyages.cpp
  src/menu.cpp
  src/menupaint.cpp
  src/menuworlds.cpp
  src/menuwin.cpp
  src/debrief.cpp
  src/voyageviewer.cpp
)
add_executable(refall ${REFALL_GAME_SOURCES})
add_executable(refall-voyage-viewer ${REFALL_GAME_SOURCES})
target_compile_definitions(refall-voyage-viewer PRIVATE REFALL_VOYAGE_VIEWER)
# The campaign (data/campaign.tsv) is built in as a byte array (the game reads the file from the sources first).
set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/data/campaign.tsv)
file(READ ${CMAKE_SOURCE_DIR}/data/campaign.tsv refall_campaign_hex HEX)
string(REGEX REPLACE "([0-9a-f][0-9a-f])" "0x\\1," refall_campaign_arr "${refall_campaign_hex}")
file(WRITE ${CMAKE_BINARY_DIR}/generated/campaign.tsv.inc.tmp "${refall_campaign_arr}\n")
configure_file(${CMAKE_BINARY_DIR}/generated/campaign.tsv.inc.tmp ${CMAKE_BINARY_DIR}/generated/campaign.tsv.inc COPYONLY)
# The standalone build: the menu's music and the gamepad mappings built in too; on Windows the game's icon, and no
# console window.
if(REFALL_STANDALONE)
  foreach(f data/menu_music.mp3 third_party/gamecontrollerdb.txt)
    get_filename_component(name ${f} NAME)
    set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS ${CMAKE_SOURCE_DIR}/${f})
    file(READ ${CMAKE_SOURCE_DIR}/${f} hex HEX)
    string(REGEX REPLACE "([0-9a-f][0-9a-f])" "0x\\1," arr "${hex}")
    file(WRITE ${CMAKE_BINARY_DIR}/generated/standalone/${name}.inc.tmp "${arr}\n")
    configure_file(${CMAKE_BINARY_DIR}/generated/standalone/${name}.inc.tmp
                   ${CMAKE_BINARY_DIR}/generated/standalone/${name}.inc COPYONLY)
  endforeach()
  if(WIN32)
    target_sources(refall PRIVATE data/refall.rc)
    if(MSVC)
      target_link_options(refall PRIVATE /SUBSYSTEM:WINDOWS /ENTRY:mainCRTStartup)
    else() # (MinGW, clang, zig cc)
      target_link_options(refall PRIVATE -Wl,--subsystem,windows)
    endif()
  endif()
endif()
# Offline renders run headless on the GPU through EGL where it exists (Linux).
if(UNIX AND NOT APPLE)
  find_package(OpenGL QUIET COMPONENTS EGL)
endif()
foreach(t refall refall-voyage-viewer)
  target_include_directories(${t} PRIVATE ${CMAKE_BINARY_DIR}/generated)
  if(OpenGL_EGL_FOUND)
    target_link_libraries(${t} PRIVATE OpenGL::EGL)
    target_compile_definitions(${t} PRIVATE REFALL_HAVE_EGL)
  endif()
  target_link_libraries(${t} PRIVATE refallrender refallcore glfw glad)
  # Gamepad mappings (SDL_GameControllerDB): looked up next to the executable, then in the sources.
  target_compile_definitions(${t} PRIVATE REFALL_SOURCE_DIR="${CMAKE_SOURCE_DIR}")
endforeach()
add_custom_command(TARGET refall POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different
                   ${CMAKE_SOURCE_DIR}/third_party/gamecontrollerdb.txt $<TARGET_FILE_DIR:refall>/gamecontrollerdb.txt)

# refall-scope: shows what the analysis hears in a song (structure, scene levels, pulses, spectrum, beats).
add_executable(refall-scope src/scope.cpp)
target_link_libraries(refall-scope PRIVATE refallcore glfw glad)

foreach(t refallcore refallrender refall refall-voyage-viewer refall-scope)
  target_compile_definitions(${t} PRIVATE GLFW_INCLUDE_NONE)
  if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
    target_compile_options(${t} PRIVATE -Wall -Wno-unused-function -Wno-missing-field-initializers)
  endif()
endforeach()

# Python wheel (scikit-build-core): the binaries and data go inside the refall package.
if(SKBUILD)
  install(TARGETS refall refall-voyage-viewer refall-scope RUNTIME DESTINATION refall/bin)
  install(FILES third_party/gamecontrollerdb.txt data/campaign.tsv data/menu_music.mp3 DESTINATION refall/bin)
endif()
