# Demo Tasks for OneTool
# Usage: just demo::<task>

set dotenv-load := true

# Demo directory (source_directory for submodule compatibility)
_dir := source_directory()

# ============================================================================
# CORE
# ============================================================================

# Show available commands
default:
    @just --list --unsorted

# Run MCP server with demo config
serve *args:
    OT_CWD={{ _dir }} uv run onetool {{ args }}

# Run benchmark scenarios (TUI picker)
bench *args:
    OT_CWD={{ _dir }} uv run bench run --tui --csv {{ args }}

# ============================================================================
# SETUP & CLEANUP
# ============================================================================

# Download demo assets (database only)
setup:
    @echo "=== Downloading Northwind database ==="
    @mkdir -p {{ _dir }}/data
    curl -sL -o {{ _dir }}/data/northwind.db \
        https://github.com/jpwhite3/northwind-SQLite3/raw/main/dist/northwind.db
    @echo "=== Demo setup complete ==="

# Remove demo assets and generated files
clean:
    rm -rf {{ _dir }}/data {{ _dir }}/db {{ _dir }}/tmp {{ _dir }}/.onetool/logs
    @echo "Demo assets cleaned"
