cmake_minimum_required(VERSION 3.15...3.26)

project(humanleague LANGUAGES CXX)

if (NOT SKBUILD)
  message(WARNING "\
  This CMake file is meant to be executed using 'scikit-build'. Running
  it directly will almost certainly not produce the desired result. If
  you are a user trying to install this package, please use the command
  below, which will install all necessary build dependencies, compile
  the package in an isolated environment, and then install it.
  =====================================================================
   $ pip install .
  =====================================================================
  If you are a software developer, and this is your own package, then
  it is usually much more efficient to install the build dependencies
  in your environment once and use the following command that avoids
  a costly creation of a new virtual environment at every compilation:
  =====================================================================
   $ pip install nanobind scikit-build-core[pyproject]
   $ pip install --no-build-isolation -ve .
  =====================================================================
  You may optionally add -Ceditable.rebuild=true to auto-rebuild when
  the package is imported. Otherwise, you need to re-run the above
  after editing C++ files.")
endif()

# Try to import all Python components potentially needed by nanobind
find_package(Python 3.12
  REQUIRED COMPONENTS Interpreter Development.Module
  OPTIONAL_COMPONENTS Development.SABIModule)

# Import nanobind through CMake's find_package mechanism
find_package(nanobind CONFIG REQUIRED)

# We are now ready to compile the actual extension module
nanobind_add_module(
  humanleague_ext

  # Target the stable ABI for Python 3.12+, which reduces
  # the number of binary wheels that must be built. This
  # does nothing on older Python versions
  STABLE_ABI

  # Build libnanobind statically
  NB_STATIC
  # NB_SHARED creates path issues

  # Source code goes here
  src/Index.cpp
  src/QIS.cpp
  src/StatFuncs.cpp
  src/TestReduce.cpp
  src/TestStatFuncs.cpp
  src/Integerise.cpp
  src/QISI.cpp
  src/Sobol.cpp
  src/TestIndex.cpp
  src/TestSlice.cpp
  src/UnitTester.cpp
  src/module.cpp
  src/SobolImpl.cpp
  src/TestNDArray.cpp
  src/TestSobol.cpp
)

target_compile_definitions(humanleague_ext PUBLIC PYTHON_MODULE)

# Install directive for scikit-build-core
install(TARGETS humanleague_ext LIBRARY DESTINATION humanleague)

