cmake_minimum_required(VERSION 3.15...3.27)
project(
  ${SKBUILD_PROJECT_NAME}
  VERSION ${SKBUILD_PROJECT_VERSION}
  LANGUAGES C CXX)

set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

if(NOT CMAKE_BUILD_TYPE OR CMAKE_BUILD_TYPE STREQUAL "")
  set(CMAKE_BUILD_TYPE
      "Release"
      CACHE STRING "" FORCE)
  message(STATUS "Set build type to default: ${CMAKE_BUILD_TYPE}")
else()
  message(STATUS "Your build type: ${CMAKE_BUILD_TYPE}")
endif()
if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O0 -ggdb")
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O0 -ggdb")
elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O3")
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O3")
endif()

set(CMAKE_CXX_STANDARD 17)
set(PYBIND11_CPP_STANDARD -std=c++17)
include_directories(BEFORE ${PROJECT_BINARY_DIR} ${PROJECT_SOURCE_DIR})
include_directories(${PYBIND11_INCLUDE_DIR})

set(BUILD_SHARED_LIBS OFF)

include(FetchContent)
set(ZLIB_COMPAT ON)
set(ZLIB_ENABLE_TESTS OFF)
set(ZLIBNG_ENABLE_TESTS OFF)
set(WITH_GZFILEOP ON)
# set(WITH_NEW_STRATEGIES OFF)
set(WITH_GTEST OFF)
# Don't install zlib static library - delocate-wheel will fail trying to parse
# .a files as Mach-O binaries on macOS
set(SKIP_INSTALL_LIBRARIES ON)
set(SKIP_INSTALL_ALL ON)
add_subdirectory(zlib-ng SYSTEM)
set(SKIP_INSTALL_LIBRARIES OFF)
set(SKIP_INSTALL_ALL OFF)

set(MAIN_SRCS decode.cpp enumerate.cpp jsontool.cpp main.cpp overzoom.cpp
              tile-join.cpp)

file(GLOB HEADERS *.hpp *.h jsonpull/*.h)
set(SOURCES
    clip.cpp
    compression.cpp
    csv.cpp
    dirtiles.cpp
    evaluator.cpp
    flatgeobuf.cpp
    geobuf.cpp
    geocsv.cpp
    geojson-loop.cpp
    geojson.cpp
    geometry.cpp
    json_logger.cpp
    jsonpull/jsonpull.c
    mbtiles.cpp
    memfile.cpp
    mvt.cpp
    plugin.cpp
    pmtiles_file.cpp
    pool.cpp
    projection.cpp
    read_json.cpp
    serial.cpp
    sqlite3.c
    text.cpp
    tile.cpp
    unit.cpp
    visvalingam.cpp
    write_json.cpp)

add_library(${PROJECT_NAME} ${SOURCES} ${HEADERS})
target_link_libraries(${PROJECT_NAME} zlib m dl pthread)
# Note: We intentionally don't install the static library into the wheel. It's
# only needed at build time (linked into executables and the Python extension).
# Installing it causes delocate-wheel to fail on macOS because it tries to parse
# .a files as Mach-O binaries.

set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY})

set(SRCS decode.cpp enumerate.cpp jsontool.cpp main.cpp overzoom.cpp
         tile-join.cpp)
foreach(src ${SRCS})
  string(REGEX REPLACE "(^.*/|.cpp$)" "" exe ${src})
  if(${src} STREQUAL "main.cpp")
    set(exe tippecanoe)
    add_executable(${exe} ${src})
    set_target_properties(${exe} PROPERTIES OUTPUT_NAME tippecanoe)
  else()
    add_executable(${exe} ${src})
  endif()
  target_link_libraries(${exe} ${PROJECT_NAME})
  set_target_properties(${exe} PROPERTIES PREFIX "__cubao_tippecanoe_")
  set_target_properties(${exe} PROPERTIES SUFFIX ".exe")
  install(TARGETS ${exe} RUNTIME DESTINATION ${SKBUILD_PROJECT_NAME})
endforeach(src)

find_package(Python REQUIRED COMPONENTS Interpreter Development.Module)
find_package(pybind11 CONFIG REQUIRED)

python_add_library(_core MODULE pybind11.cpp WITH_SOABI)
target_link_libraries(_core PRIVATE pybind11::headers ${PROJECT_NAME})
target_compile_definitions(_core PRIVATE VERSION_INFO=${PROJECT_VERSION})
install(TARGETS _core DESTINATION ${SKBUILD_PROJECT_NAME})
