# ===----------------------------------------------------------------------=== #
#
# This file is Modular Inc proprietary.
#
# ===----------------------------------------------------------------------=== #

# ===----------------------------------------------------------------------=== #
#
# File originates from:
#   Repo:   git@github.com:psf/black.git
#   Commit: d4a85643a465f5fae2113d07d22d021d4af4795a
#   Path:   src/black/__init__.py
#
# ===----------------------------------------------------------------------=== #

# Grammar for 2to3. This grammar supports Python 2.x and 3.x.

# NOTE WELL: You should also follow all the steps listed at
# https://devguide.python.org/grammar/

# Start symbols for the grammar:
#	file_input is a module or sequence of commands read from an input file;
#	single_input is a single interactive statement;
#	eval_input is the input for the eval() and input() functions.
# NB: compound_stmt in single_input is followed by extra NEWLINE!
file_input: (NEWLINE | stmt)* ENDMARKER
single_input: NEWLINE | simple_stmt | compound_stmt NEWLINE
eval_input: testlist NEWLINE* ENDMARKER

decorator: '@' namedexpr_test NEWLINE
decorators: decorator+
decorated: decorators (classdef | funcdef | async_funcdef | if_stmt | for_stmt | var_stmt NEWLINE | comptime_stmt | import_stmt)
async_funcdef: ASYNC funcdef
where_clause: WHERE top_test
# Mojo terms: metaparams [..] = parameter list; parameters (..) = argument list;
# captures {..} = capture list (production names kept from black's Python grammar).
funcdef: ('def' | MLIR_REGION) NAME [metaparams] parameters [named_effect*] [global_effects] [captures] ['->' result_type] (where_clause)* ':' suite
global_effects: global_effect_keyword*
global_effect_keyword: 'raises' [raises_type] | 'escaping' | 'capturing'
# `raises_type` lists allowed shapes after `raises` in global_effects. It
# must not use the full `typeconvexpr` production: that can begin with `{`
# and would steal the capture list from `raises {a, b}`. Subscripts use the
# same `testlist_gexp` as inside `[...]` elsewhere in the grammar.
raises_type: dotted_name ( '[' testlist_gexp ']' )* | '(' [testlist_gexp] ')'
named_effect: NAME ['(' STRING ')']
captures: '{' [capture_list] '}'
capture_list: capture_item (',' capture_item)* [',']
# Support both specific captures (e.g., "var x", "var x^", "mut y") and
# global capture modes (e.g., "var", "var^", "imm"). The move marker '^'
# follows either VAR or a bare name ("var x^", "var^", "x^").
capture_item: (VAR [NAME ['^'] | '^' [NAME]]) | (IMM [NAME]) | (MUT [NAME]) | (REF [NAME]) | (NAME ['^' | NAME])
metaparams: '[' [typedargslist] ']'
parameters: '(' [typedargslist] ')'
result_type: [REF '[' test [',' test [',']] ']'] (functype | generatortype | or_expr)

# The following definition for typedarglist is equivalent to this set of rules:
#
#     arguments = argument (',' argument)*
#     argument = tfpdef ['=' test]
#     kwargs = '**' tname [',']
#     args = '*' [tname_star]
#     kwonly_kwargs = (',' argument)* [',' [kwargs]]
#     args_kwonly_kwargs = args kwonly_kwargs | kwargs
#     poskeyword_args_kwonly_kwargs = arguments [',' [args_kwonly_kwargs]]
#     typedargslist_no_posonly  = poskeyword_args_kwonly_kwargs | args_kwonly_kwargs
#     typedarglist = arguments ',' '/' [',' [typedargslist_no_posonly]])|(typedargslist_no_posonly)"
#
# It needs to be fully expanded to allow our LL(1) parser to work on it.

convention: VAR | (OUT ['[' test [',' test [',']] ']']) | IMM | MUT | DEINIT | (REF ['[' test [',' test [',']] ']'])
#tname: NAME [metaparams] [':' test]

typedargslist: ((([convention] ['**'|'*'] tfpdef ['=' test])|'/'|'*'|'//') [','])*

tname: NAME [metaparams] [':' (type_test|star_expr)]

tname_star: NAME [':' (test|star_expr)]
tfpdef: tname | '(' tfplist ')'
tfplist: tfpdef (',' tfpdef)* [',']

# The following definition for varargslist is equivalent to this set of rules:
#
#     arguments = argument (',' argument )*
#     argument = vfpdef ['=' test]
#     kwargs = '**' vname [',']
#     args = '*' [vname]
#     kwonly_kwargs = (',' argument )* [',' [kwargs]]
#     args_kwonly_kwargs = args kwonly_kwargs | kwargs
#     poskeyword_args_kwonly_kwargs = arguments [',' [args_kwonly_kwargs]]
#     vararglist_no_posonly = poskeyword_args_kwonly_kwargs | args_kwonly_kwargs
#     varargslist = arguments ',' '/' [','[(vararglist_no_posonly)]] | (vararglist_no_posonly)
#
# It needs to be fully expanded to allow our LL(1) parser to work on it.

varargslist: vfpdef ['=' test ](',' vfpdef ['=' test])* ',' '/' [',' [
                     ((vfpdef ['=' test] ',')* ('*' [vname] (',' vname ['=' test])*
                            [',' ['**' vname [',']]] | '**' vname [','])
                            | vfpdef ['=' test] (',' vfpdef ['=' test])* [','])
                     ]] | ((vfpdef ['=' test] ',')*
                     ('*' [vname] (',' vname ['=' test])*  [',' ['**' vname [',']]]| '**' vname [','])
                     | vfpdef ['=' test] (',' vfpdef ['=' test])* [','])

vname: NAME
vfpdef: vname | '(' vfplist ')'
vfplist: vfpdef (',' vfpdef)* [',']

stmt: simple_stmt | compound_stmt
simple_stmt: small_stmt (';' small_stmt)* [';'] NEWLINE
small_stmt: (expr_stmt | print_stmt | del_stmt | pass_stmt | flow_stmt |
             import_stmt | global_stmt | exec_stmt | assert_stmt)
expr_stmt: testlist_star_expr_stmt (annassign | augassign (yield_expr|testlist) |
                     ('=' (yield_expr|testlist_star_expr))*)
top_expr_stmt: testlist_star_expr (annassign | augassign (yield_expr|testlist) |
                     ('=' (yield_expr|testlist_star_expr))*)
annassign: ':' test ['=' (yield_expr|testlist_star_expr)]
testlist_star_expr_stmt: (if_else_test|star_expr) (',' (test|star_expr))* [',']
testlist_star_expr: (test|star_expr) (',' (test|star_expr))* [',']
augassign: ('+=' | '-=' | '*=' | '@=' | '/=' | '%=' | '&=' | '|=' | '^=' |
            '<<=' | '>>=' | '**=' | '//=')
# For normal and annotated assignments, additional restrictions enforced by the interpreter
print_stmt: 'print' ( [ test (',' test)* [','] ] |
                      '>>' test [ (',' test)+ [','] ] )
del_stmt: 'del' exprlist
pass_stmt: 'pass'
flow_stmt: break_stmt | continue_stmt | return_stmt | raise_stmt | yield_stmt
break_stmt: 'break'
continue_stmt: 'continue'
return_stmt: 'return' [testlist_star_expr]
yield_stmt: yield_expr
raise_stmt: 'raise' [test ['from' test | ',' test [',' test]]]
import_stmt: import_name | import_from
import_name: 'import' dotted_as_names
import_from: ('from' ('.'* dotted_name | '.'+)
              'import' ('*' | '(' import_as_names ')' | import_as_names))
import_as_name: NAME ['as' NAME]
dotted_as_name: dotted_name ['as' NAME]
import_as_names: import_as_name (',' import_as_name)* [',']
dotted_as_names: '.'* dotted_as_name (',' '.'* dotted_as_name)*
dotted_name: NAME ('.' NAME)*
global_stmt: ('global' | 'nonlocal') NAME (',' NAME)*
exec_stmt: 'exec' expr ['in' test [',' test]]
assert_stmt: 'assert' test [',' test]
var_stmt: (VAR|REF) top_expr_stmt
alias_target: NAME | '(' alias_target_list ')'
alias_target_list: alias_target (',' alias_target)*
# Trailing 'where' clauses may follow the alias type (if any) and precede the
# '=' initializer (if any). They are only meaningful on parameterized aliases;
# the surrounding parser enforces that restriction.
alias_stmt_body: alias_target_list [metaparams] (
    ':' test (where_clause)* ['=' (yield_expr|testlist_star_expr)] |
    (where_clause)* '=' (yield_expr|testlist_star_expr)
)
comptime_assert_stmt_body: 'assert' test [',' test]
comptime_stmt: COMPTIME (comptime_assert_stmt_body NEWLINE | alias_stmt_body NEWLINE | if_stmt | for_stmt)


compound_stmt: if_stmt | while_stmt | for_stmt | try_stmt | with_stmt | funcdef | classdef | decorated | async_stmt | match_stmt | comptime_stmt
async_stmt: ASYNC (funcdef | with_stmt | for_stmt)
if_stmt: 'if' namedexpr_test ':' suite ('elif' namedexpr_test ':' suite)* ['else' ':' suite]
while_stmt: 'while' namedexpr_test ':' suite ['else' ':' suite]
for_stmt: 'for' exprlist 'in' testlist_star_expr ':' suite ['else' ':' suite]
try_stmt: ('try' ':' suite
           ((except_clause ':' suite)+
	    ['else' ':' suite]
	    ['finally' ':' suite] |
	   'finally' ':' suite))
with_stmt: 'with' asexpr_test (',' asexpr_test)*  ':' suite

# NB compile.c makes sure that the default except clause is last
except_clause: 'except' ['*'] [test [(',' | 'as') test]]
suite: simple_stmt | NEWLINE INDENT stmt+ DEDENT

# Backward compatibility cruft to support:
# [ x for x in lambda: True, lambda: False if x() ]
# even while also allowing:
# lambda x: 5 if x else 2
# (But not a mix of the two)
testlist_safe: old_test [(',' old_test)+ [',']]
old_test: or_test | old_lambdef
# old_lambdef mirrors lambdef's Mojo signature extension (see the comment at lambdef)
# so a Mojo lambda also parses where old_test is reached (e.g. a comprehension's `if`).
# Only the header is mirrored: the body stays old_test, which cannot be a bare
# conditional, so a trailing `if` stays the comprehension's filter instead of
# becoming a ternary that would swallow it.
old_lambdef: 'lambda' ([metaparams] [parameters [named_effect*] [global_effects]] [captures] ['->' result_type] | [varargslist]) ':' old_test

namedexpr_test: asexpr_test [':=' asexpr_test]

# This is actually not a real rule, though since the parser is very
# limited in terms of the strategy about match/case rules, we are inserting
# a virtual case (<expr> as <expr>) as a valid expression. Unless a better
# approach is thought, the only side effect of this seem to be just allowing
# more stuff to be parser (which would fail on the ast).
asexpr_test: test ['as' test]

test: functype | generatortype | top_test
top_test: [COMPTIME] if_else_test
if_else_test: or_test ['if' or_test 'else' test] | lambdef
or_test: and_test ('or' and_test)*
and_test: not_test ('and' not_test)*
not_test: 'not' not_test | comparison
comparison: expr (comp_op expr)*
comp_op: '<'|'>'|'=='|'>='|'<='|'<>'|'!='|'in'|'not' 'in'|'is'|'is' 'not'
star_expr: '*' expr
expr: (VAR exprlist) | (REF exprlist) | or_expr
or_expr: xor_expr ('|' xor_expr)*
xor_expr: and_expr ('^' [and_expr | '.' NAME trailer* ['**' factor] (('*'|'@'|'/'|'%'|'//') factor)* (('+' | '-') term)* (('<<' | '>>') arith_expr)* ('&' shift_expr)*])*
and_expr: shift_expr ('&' shift_expr)*
shift_expr: arith_expr (('<<'|'>>') arith_expr)*
arith_expr: term (('+'|'-') term)*
term: factor (('*'|'@'|'/'|'%'|'//') factor)*
factor: ('+'|'-'|'~') factor | power
power: [AWAIT] atom trailer* ['**' factor]
# Contextually inferred member references (`.member`) are atoms so they parse
# wherever an expression is expected: call args, subscripts, annotations, etc.
atom: ('(' [yield_expr|testlist_gexp] ')' |
       '[' [listmaker] ']' |
       '{' [dictsetmaker] '}' |
       '`' testlist1 '`' |
       NAME | NUMBER | STRING+ | '.' NAME | '.' '.' '.')
listmaker: (namedexpr_test|star_expr) ( old_comp_for | (',' (namedexpr_test|star_expr))* [','] )
testlist_gexp: (namedexpr_test|star_expr) ( old_comp_for | (',' (namedexpr_test|star_expr))* [','] )
# A Mojo lambda mirrors the `funcdef` signature (optional metaparams, an optional
# parenthesized arg list, captures, and return type), with an expression body instead
# of a suite. The whole arg list is optional (`lambda {} -> R: e`, `lambda -> R: e`,
# `lambda: e` are all valid); effects nest under it because the compiler only accepts
# them after a parenthesized arg list. The Mojo branch and the Python `varargslist`
# branch overlap: both can start with `(` (Python via a tuple-arg `vfpdef`) and both
# are nullable. pgen merges the shared transitions; the token after `(` (typed vs bare
# name) picks the reading, and both format identically, so the merge is benign. Only
# `[` / `{` / `->` are unique to the Mojo branch; a bare NAME / `*` / `**` stays
# exclusively Python — making the whole production a superset of Python's form.
lambdef: 'lambda' ([metaparams] [parameters [named_effect*] [global_effects]] [captures] ['->' result_type] | [varargslist]) ':' test
trailer: '(' [arglist] ')' | '{' [dictsetmaker] '}' | '[' [subscriptlist] ']' | '.' NAME
subscriptlist: (subscript|star_expr) (',' (subscript|star_expr))* [',']
subscript: test [':=' test] | [test] ':' [test] [sliceop] | test ['=' [test] ':' [test] [sliceop]] | test ['=' test] | '**' test
sliceop: ':' [test]
exprlist: (expr|star_expr) (',' (expr|star_expr))* [',']
testlist: test (',' test)* [',']
dictsetmaker: ( ((test ':' asexpr_test | test '=' asexpr_test | test | '**' expr)
                 (comp_for | (',' (test ':' asexpr_test | test '=' asexpr_test | test | '**' expr))* [','])) |
                ((test [':=' test] | star_expr)
		 (comp_for | (',' (test [':=' test] | star_expr))* [','])) )

# Type-expression subgrammar (enables functype within bitwise chains only in type contexts)
type_test: type_or_expr
type_or_expr: type_xor_expr ('|' type_xor_expr)*
type_xor_expr: type_and_expr ('^' [type_and_expr | '.' NAME trailer* ['**' factor] (('*'|'@'|'/'|'%'|'//') type_factor)* (('+' | '-') type_term)* (('<<' | '>>') type_arith_expr)* ('&' type_shift_expr)*])*
type_and_expr: type_shift_expr ('&' type_shift_expr)*
type_shift_expr: type_arith_expr (('<<'|'>>') type_arith_expr)*
type_arith_expr: type_term (('+'|'-') type_term)*
type_term: type_factor (('*'|'@'|'/'|'%'|'//') type_factor)*
type_factor: ('+'|'-'|'~') type_factor | type_power
type_power: [AWAIT] type_atom trailer* ['**' factor]
type_atom: functype | generatortype | atom

classdef: STRUCT NAME [metaparams] ['(' [arglist] ')'] (where_clause)* ':' suite | ('class' | TRAIT | EXTENSION) NAME [metaparams] ['(' [arglist] ')'] ':' suite

typeconvexpr: atom trailer* | functype | generatortype
typeconv: (['*'|VAR|IMM|MUT|OUT|DEINIT] ['*'|'**'] typeconvexpr [':' ['*'|'**'] test]) | '/' | '*' | '//'
# A `thin` function type may carry trailing `where` clauses constraining its own
# parameters. The clauses bind to the innermost function type, so a declaration
# whose result type is a function type must parenthesize it to keep a trailing
# `where` of its own; the grammar accepts them on any function type and leaves
# the `thin` restriction to the compiler.
functype: [ASYNC] 'def' [metaparams] '(' [typeconv (',' typeconv)*] [','] ')' named_effect* [global_effects] [captures] ['[' test ']'] ['->' test] (where_clause)*
# `__generator_type[Idx: Int] ToT` — Mojo generator type literal (`!lit.generator`).
generatortype: GENERATOR_TYPE [metaparams] type_test

arglist: argument (',' argument)* [',']

# "test '=' test" is really "keyword '=' test", but we have no such token.
# These need to be in a single rule to avoid grammar that is ambiguous
# to our LL(1) parser. Even though 'test' includes '*expr' in star_expr,
# we explicitly match '*' here, too, to give it proper precedence.
# Illegal combinations and orderings are blocked in ast.c:
# multiple (test comp_for) arguments are blocked; keyword unpackings
# that precede iterable unpackings are blocked; etc.
argument: ( test [comp_for] (where_clause)* |
            test ':=' test [comp_for] |
            test 'as' test |
            test '=' asexpr_test |
	    '**' test |
            '*' test )

comp_iter: comp_for | comp_if
comp_for: [ASYNC] 'for' exprlist 'in' or_test [comp_iter]
comp_if: 'if' old_test [comp_iter]

# As noted above, testlist_safe extends the syntax allowed in list
# comprehensions and generators. We can't use it indiscriminately in all
# derivations using a comp_for-like pattern because the testlist_safe derivation
# contains comma which clashes with trailing comma in arglist.
#
# This was an issue because the parser would not follow the correct derivation
# when parsing syntactically valid Python code. Since testlist_safe was created
# specifically to handle list comprehensions and generator expressions enclosed
# with parentheses, it's safe to only use it in those. That avoids the issue; we
# can parse code like set(x for x in [],).
#
# The syntax supported by this set of rules is not a valid Python 3 syntax,
# hence the prefix "old".
#
# See https://bugs.python.org/issue27494
old_comp_iter: old_comp_for | old_comp_if
old_comp_for: [ASYNC] 'for' exprlist 'in' testlist_safe [old_comp_iter]
old_comp_if: 'if' old_test [old_comp_iter]

testlist1: test (',' test)*

# not used in grammar, but may appear in "node" passed from Parser to Compiler
encoding_decl: NAME

yield_expr: 'yield' [yield_arg]
yield_arg: 'from' test | testlist_star_expr


# 3.10 match statement definition
#
# Soft keywords use double quotes ("match", "case", "__match").
#
# Two layouts are accepted after the subject colon:
#   1. Python style: NEWLINE INDENT case_block+ DEDENT
#   2. Mojo style:   NEWLINE case_block+   (cases share the match indent)
# Mojo mode formatting always emits layout (2).

# PS: normally the grammar is much much more restricted, but
# at this moment for not trying to bother much with encoding the
# exact same DSL in a LL(1) parser, we will just accept an expression
# and let the ast.parse() step of the safe mode to reject invalid
# grammar.

# The reason why it is more restricted is that, patterns are some
# sort of a DSL (more advanced than our LHS on assignments, but
# still in a very limited python subset). They are not really
# expressions, but who cares. If we can parse them, that is enough
# to reformat them.

match_stmt: ("match" | "__match") subject_expr ':' NEWLINE (INDENT case_block+ DEDENT | case_block+)

# This is more permissive than the actual version. For example it
# accepts `match *something:`, even though single-item starred expressions
# are forbidden.
subject_expr: (namedexpr_test|star_expr) (',' (namedexpr_test|star_expr))* [',']

# cases
case_block: "case" patterns [guard] ':' suite
guard: 'if' namedexpr_test
patterns: pattern (',' pattern)* [',']
pattern: (expr|star_expr) ['as' expr]
