# Maintainer: Daniel Langbein <daniel@systemli.org>

# This PKGBUILD is based on the instructions from the Arch Linux wiki:
# https://wiki.archlinux.org/title/Python_package_guidelines

_name=netcup-dns
pkgname="python-$_name-git"
pkgver=r20.cdad070
pkgrel=1
pkgdesc='Set DNS records to public IP using netcup DNS API'
arch=(any)
url="https://codeberg.org/privacy1st/$_name"
license=('MIT')

depends=(python exec-notify python-nc-dnsapi python-requests)
# TODO: Needs to be updated to use hatchling instead of setuptools
makedepends=(git python-build python-installer python-wheel)

source=("git+https://codeberg.org/privacy1st/$_name.git")
b2sums=(SKIP)

# If there are no tags then use number of revisions since beginning of the history:
# https://wiki.archlinux.org/title/VCS_package_guidelines
pkgver() {
    cd "$_name"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

prepare() {
    git -C "$srcdir/$_name" clean -dfx
}

build() {
    # cd "$_name-$pkgver"
    cd "$_name"
    python -m build --wheel --no-isolation
}

package() {
    # cd "$_name-$pkgver"
    cd "$_name"
    python -m installer --destdir="$pkgdir" dist/*.whl
}

check(){
    cd "$srcdir/$_name"

    # For nosetests
    # nosetests

    # For pytest
    # pytest
}
