# Maintainer: Nicholas Glazer <nicholasglazer at protonmail dot com>
pkgname=python-gnosis-mcp
pkgver=0.10.11
pkgrel=1
pkgdesc="Zero-config MCP server for searchable documentation (SQLite default, PostgreSQL optional)"
arch=('any')
url="https://github.com/nicholasglazer/gnosis-mcp"
license=('MIT')
depends=('python>=3.11' 'python-mcp>=1.20' 'python-aiosqlite>=0.20')
optdepends=('python-asyncpg: PostgreSQL backend'
            'python-onnxruntime: local ONNX embeddings'
            'python-tokenizers: local ONNX embeddings'
            'python-numpy: local ONNX embeddings'
            'python-httpx: web crawling'
            'python-trafilatura: web crawling')
makedepends=('python-build' 'python-installer' 'python-hatchling')
source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/44/c1/93fcece89fc1e73254033d62919b91fab24b665c584fd6e5c853a73a9ff5/gnosis_mcp-$pkgver.tar.gz")
sha256sums=('03d360c1e0c3c33aefd6d644bde3836785c2d38f244b7d1008fd2b242a2d3b3f')

build() {
    cd "gnosis_mcp-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "gnosis_mcp-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
