continue -- continue with the next iteration of a loop

Usage:

continue x
Inputs:
- x
Consequences:
- the currently executing list-clause of a for-loop or while-loop is finished, and iteration continues with the do-clause or the next iteration of the loop, if any. The value x is added to the list being accumulated. If x is omitted, then no value is added to the list, and the statement may be used in a do-clause.
- Alternatively, as a debugger command, causes execution to be resumed, starting with the current expression.

Description

i1 : for i from 1 to 4 list (continue 4; print ho) do print hi
hi
hi
hi
hi

o1 = {4, 4, 4, 4}

o1 : List

i2 : for i from 1 to 4 list (continue ; 14) do print hi
hi
hi
hi
hi

o2 = {}

o2 : List

i3 : for i from 1 to 4 list 14 do print hi
hi
hi
hi
hi

o3 = {14, 14, 14, 14}

o3 : List

i4 : i = 0 ; while i < 10 do ( i = i+1; if i == 5 then continue ; print i )
1
2
3
4
6
7
8
9
10

Here is an example of the use of continue in the debugger after altering a value so continuation will not cause the error to recur.

i6 : load "Macaulay2Doc/demos/demo1.m2"

i7 : code g

o7 = /home/m2user/work/passagemath/passagemath/local/var/tmp/sage/build/
     macaulay2-1.26.06/src/M2/Macaulay2/packages/Macaulay2Doc/demos/demo1.m2:
     11:4-14:9: --source code:
     g = y -> (
          c := f(y-1);
          d := f(y-2);
          c+d)

i8 : g 2
${prefix}/share/Macaulay2/Macaulay2Doc/demos/demo1.m2:8:11:(3):[3]: error: division by zero
${prefix}/share/Macaulay2/Macaulay2Doc/demos/demo1.m2:8:11:(3): entering debugger (enter 'help' to see commands)
/home/m2user/work/passagemath/passagemath/local/var/tmp/sage/build/macaulay2-
1.26.06/src/M2/Macaulay2/packages/Macaulay2Doc/demos/demo1.m2:8:10-8:13:
--source code:
     b := 1/x;

ii9 : code f

oo9 = /home/m2user/work/passagemath/passagemath/local/var/tmp/sage/build/
      macaulay2-1.26.06/src/M2/Macaulay2/packages/Macaulay2Doc/demos/demo1.m2
      :6:5-9:9: --source code:
      f := x -> (
           a := "hi there";
           b := 1/x;
           b+1)

ii10 : x

oo10 = 0

ii11 : x = 11

oo11 = 11

ii12 : continue

      34
o12 = --
      11

o12 : QQ

For the programmer

The object continue is a keyword.

The source of this document is in Macaulay2Doc/ov_language.m2:631:0.