# Maintainer: knapset-dev <knapset-dev@users.noreply.github.com>
pkgname=knapset
pkgver=1.0.2
pkgrel=1
pkgdesc="Dependency-free Python framework for analyzing marketplace listings and optimizing compatible, budget-constrained sets"
arch=('any')
url="https://github.com/knapset-dev/knapset"
license=('MIT')
depends=('python>=3.10')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/knapset-dev/${pkgname}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('SKIP')

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  install -d "${pkgdir}/usr/lib/${pkgname}" "${pkgdir}/usr/bin"
  cp -a \
    app_paths.py main.py currency.py analyzer_core.py audit_ledger.py \
    ai_inspector.py domain_layout.py domain_weights.py set_synthesizer.py \
    extension_registry.py market_client.py market_store.py mcp_server.py \
    provider_template.py scam_utils.py web_server.py watchdog.py \
    ai_providers build_composer component_analyser configs docs \
    extensions info_providers marketplace scam_analyser \
    "${pkgdir}/usr/lib/${pkgname}/"

  find "${pkgdir}/usr/lib/${pkgname}" -type d -name '__pycache__' -exec rm -rf {} +
  python3 -m compileall -d "/usr/lib/${pkgname}" -q "${pkgdir}/usr/lib/${pkgname}"

  cat <<'EOF' > "${pkgdir}/usr/bin/knapset"
#!/usr/bin/env python3
import sys

sys.path.insert(0, "/usr/lib/knapset")
from main import main

if __name__ == "__main__":
    main()
EOF
  chmod 755 "${pkgdir}/usr/bin/knapset"
  ln -s knapset "${pkgdir}/usr/bin/ks"

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}
