::vowel:: = ʌ|a|i|u|e|o
::consonant:: = k|kʰ|ɡ|ɡʱ|ŋ|t͡s|t͡sʰ|d͡z|d͡zʱ|ʈ|ʈʰ|ɖ|ɖʱ|ɳ|t|tʰ|d|dʱ|n|p|pʰ|b|bʱ|m|j|ɾ|l|w|s|ɦ|z|f|ɽ|ɽʱ

% Delete null onset symbol inserted by map
<ons> -> 0 / _

% Viraama (halanta): cancels the inherent vowel
ʌ् -> 0 / _

% Inherent vowel is overridden by a following vowel sign
ʌ -> 0 / _ (::vowel::)

% [X-DICT] Final schwa is retained in a closed class of postpositions
% (तिर, बाट, सँग), the adverb अब, and a few nouns (दुख, सुख).
% Not implemented: requires word-specific lexical knowledge.
% [X-MF] Verb forms also retain it, but come out correct incidentally,
% since they end in consonant clusters that block the rule below.
ʌ -> 0 / (::vowel::)(::consonant::) _ #

% Hindi/Marathi also delete the MEDIAL schwa. Nepali retains it, so omitted:
%   ʌ -> 0 / (::vowel::)N?(::consonant::) _ (?=(::consonant::)(::vowel::))

% Homorganic nasal
N -> m / _ (p|pʰ|b|bʱ|m)
N -> ŋ / _ (k|kʰ|ɡ|ɡʱ|ŋ)
N -> n / _

% व is [b] word-initially in Sanskrit-derived vocabulary (वर्ष bʌɾsʌ,
% विद्यालय, वन) but [w] between vowels (बुवा buwa, सवारी, दिवस).
% Perso-Arabic loans keep [w] initially (वकिल wʌkil) -- not visible in
% the orthography, so those need lexical entries in the map.
w -> b / # _
